ANSYS動力學分析的幾個入門例子

問題一：懸臂梁受重力作用發生大變形，求其固有頻率。 
基本過程：
1、建模
2、靜力分析  
   NLGEOM,ON 
   STRES,ON     
3、求靜力解
4、開始新的求解：modal 
   STRES,ON
   UPCOORD,1,ON  修正坐標  
   SOLVE...      
5、擴展模態解
6、察看結果   
/PREP7   
ET,1,BEAM189                          !使用beam189梁單元
MPTEMP,,,,,,,,   
MPTEMP,1,0   
MPDATA,EX,1,,210e9   
MPDATA,PRXY,1,,0.3   
MPDATA,DENS,1,,7850  
SECTYPE,   1, BEAM, RECT, secA, 0     !定義梁截面secA
SECOFFSET, CENT  
SECDATA,0.005,0.01,0,0,0,0,0,0,0,0   
K, ,,,,                               !建模與分網
K, ,2,,,
K, ,2,1,,   
LSTR,       1,       2   
LATT,1, ,1, ,       3, ,1   
LESIZE,1, , ,20, , , , ,1  
LMESH,       1   
FINISH   
/SOL                                  !靜力大變形求解
ANTYPE,0
NLGEOM,1                              
PSTRES,ON                            #p#分頁標題#e# !計及預應力效果
DK,1, , , ,0,ALL, , , , , ,   
ACEL,0,9.8,0,                         !只考慮重力作用
TIME,1   
AUTOTS,1
NSUBST,20, , ,1  
KBC,0   
SOLVE   
FINISH   
/SOLUTION   
ANTYPE,2                              !進行模態求解
MSAVE,0  
MODOPT,LANB,10   
MXPAND,10, , ,0                       !取前十階模態
PSTRES,1                              !打開預應力效應
MODOPT,LANB,10,0,0, ,OFF
UPCOORD,1,ON                          !修正坐標以得到正確的應力
PSOLVE,TRIANG                         !三角化矩陣
PSOLVE,EIGLANB                        !提取特征值和特征向量
FINISH   
/SOLU   
EXPASS,1                              !擴展模態解
PSOLVE,EIGEXP   
FINISH   

 /POST1   
SET,LIST                              !觀察結果
FINISH  
#p#分頁標題#e#問題二：循環對稱結構模態分析
這是ANSYS HELP里的例子，但那個命令流似乎有些問題，下面是整理過的命令流。 
基本過程：
1、建模
2、define cyclic
3、定義約束
4、求模態解
5、展開并察看結果
  
r1=5                                 !建模
r2=10
d1=2
nsect=24
alpha_deg=360/nsect
alpha_rad=2*acos(-1)/nsect
  
/prep7
csys,1
k,1,0,0,0
k,2,0,0,d1
k,3,r1,0,0
k,4,r1,0,d1
l,3,4
arotat,1,,,,,,1,2,alpha_deg/2
k,7,r2,0,0
k,8,r2,0,d1
l,7,8
arotat,5,,,,,,1,2,alpha_deg/2
arotat,2,,,,,,1,2,alpha_deg/2
arotat,6,,,,,,1,2,alpha_deg/2
a,5,6,10,9
mshkey,1
et,1,181
r,1,0.20
r,2,0.1
mp,ex,1,10e6
mp,prxy,1,0.3
mp,dens,1,1e-4
esize,0.5
asel,,,,1,4
aatt,,1
asel,,,,5
aatt,,2
allsel
  
CYCLIC, , , ,'CYCLIC'                !定義基本扇區
AMESH,all                            !分網
FINISH   
  
/SOL                                 !求模態解
ANTYPE,2
MODOPT,LANB,10   
MXPAND,10, , ,0  
PSTRES,0
MODOPT,LANB,10,0,0, ,OFF
DK,5, , , ,0,UZ, , , , , ,   
SOLVE   
FINISH  
  
/POST1   
SET,LIST
SET, , ,1, , , ,4,   
/CYCEXPAND, ,ON  
PLNS,U,SUM                           !觀察擴展模態
FINISH

問題三：三角平臺受諧波載荷作用,求結構響應
諧波載荷為作用在平臺上面一點的集中力，幅值為10N，頻率范圍5Hz~70Hz 
  基本過程：
1、建模
2. 求模態解
3、用模態疊加法作諧分析
4. 觀察結果
  
/PREP7                   #p#分頁標題#e#       !建模
ET,1,BEAM189
ET,2,SHELL93
R,1,0.01, , , , , ,  
MP,EX,1,210e9   
MP,PRXY,1,0.3   
MP,DENS,1,7850   
SECTYPE,   1, BEAM, RECT, secA, 0   
SECOFFSET, CENT  
SECDATA,0.005,0.008,0,0,0,0,0,0,0,0  
K, ,-0.5,,,  
K, ,0.5,,,   
K, ,,,1,
K, ,,1,1,   
K, ,-0.5,1,,
K, ,0.5,1,,  
K, ,,,0.5,   
A,4,5,6  
LSTR,       1,       5   
LSTR,       3,       4   
LSTR,       2,       6   
LSEL,S,LINE,,4,6
LATT,1,1,1, ,       7, ,1   
LSEL, , , ,ALL   
LESIZE,ALL, , ,10, , , , ,1  
LMESH,4,6   
TYPE,   2   
MSHAPE,0,2D  
MSHKEY,1
AMESH,1  
FINISH   
  
/SOL                     !為了使用模態疊加法諧分析
ANTYPE,2
MODOPT,LANB,20           !先取結構前20階模態  
MXPAND,20, , ,0  
MODOPT,LANB,20,0,0, ,OFF
KSEL,S,KP,,1,3  
DK,ALL, , , ,0,ALL, , , , , ,   
SOLVE   
FINISH  
  
!/POST1                  !最好事先看一下模態結果
!SET,LIST                !以了解模態頻率范圍
!FINISH   
  
/SOL                     !模態疊加法諧響應分析
ANTYPE,3
HROPT,MSUP   
HROUT,ON
HROPT,MSUP,20, ,
HROUT,ON,OFF,0   
F,177,FY,-10,    #p#分頁標題#e#        !施加10N的力在節點177的負Y方向
HARFRQ,5,70,             !載荷的強制頻率范圍
NSUBST,200,  
KBC,1   
ALPHAD,5,   
SOLVE   
FINISH   
  
/POST26                 !察看位移響應
FILE,,rfrq
NUMVAR,20  
NSOL,2,139,U,Y,  
PLVAR,2
FINISH

問題四：三角平臺受一地震譜激勵,求應力分布和支反力 
基本過程：
1、建模
2、求模態解
3、求譜解
4、擴展模態
5、模態合并
6、觀察結果
  
/PREP7             !建模
ET,1,BEAM189
ET,2,SHELL93
R,1,0.01, , , , , ,  
MP,EX,1,210e9   
MP,PRXY,1,0.3   
MP,DENS,1,7850  
SECTYPE,   1, BEAM, RECT, secA, 0   
SECOFFSET, CENT  
SECDATA,0.005,0.008,0,0,0,0,0,0,0,0  
   
K, ,-0.5,,,  
K, ,0.5,,,   
K, ,,,1,
K, ,,1,1,   
K, ,-0.5,1,,
K, ,0.5,1,,  
K, ,,,0.5,   
A,4,5,6  
LSTR,       1,       5   
LSTR,       3,       4   
LSTR,       2,       6   
LSEL,S,LINE,,4,6  
LATT,1,1,1, ,       7, ,1   
LSEL, , , ,ALL
LESIZE,ALL, , ,10, , , , ,1  
LMESH,4,6   
TYPE,   2   
MSHAPE,0,2D  
MSHKEY,1
AMESH,1  
FINISH   
  
/SOL              !取前十階模態
ANTYPE,2
MODOPT,LANB,10   
KSEL,S,KP,,1,3  
DK,ALL, , , ,0,ALL, , , , , ,   
SOLVE   
FINISH #p#分頁標題#e#  
  
/SOL                 !譜分析
ANTYPE,8
SPOPT,SPRS,10,1
SVTYP,3
SED,0,1,0,         !給出激勵方向
FREQ,0.25,1.34,6.73,14.6,28.9,0,0,0,0    !激勵譜
SV,0,0.00073,0.00016,0.00034,0.00034,0.00052,   
SOLVE   
FINISH   
  
/SOL                  !擴展模態
ANTYPE,2
EXPASS,1
MXPAND,10,0,0,1,0.001,   
SOLVE   
FINISH   
  
/SOL                 !模態合并
ANTYPE,8
SRSS,0.001,DISP  
SOLVE   
  
/POST1            !觀察結果
SET,LIST  
/INPUT,,mcom
PRRSOL,F
FINISH  

問題五：三角平臺受時程載荷作用,求應力分布和變形過程
  
基本過程：
1、建模
2. 施加隨時間變化載荷，定義載荷步
3、求解
4. 在POST1和POST26中觀察結果
  
/PREP7                             !建模
ET,1,BEAM189
ET,2,SHELL93  
R,1,0.01, , , , , ,  
MP,EX,1,210e9   
MP,PRXY,1,0.3   
MP,DENS,1,7850   
SECTYPE,   1, BEAM, RECT, secA, 0   
SECOFFSET, CENT  
SECDATA,0.005,0.008,0,0,0,0,0,0,0,0  
K, ,-0.5,,,  
K, ,0.5,,,   
K, ,,,1,
K, ,,1,1,   
K, ,-0.5,1,,
K, ,0.5,1,,  
K, ,,,0.5,   
A,4,5,6  
LSTR,       1,       5   
LSTR,       3,       4   #p#分頁標題#e#
LSTR,       2,       6   
LSEL,S,LINE,,4,6
LATT,1,1,1, ,       7, ,1   
LSEL, , , ,ALL   
LESIZE,ALL, , ,10, , , , ,1  
LMESH,4,6   
TYPE,   2   
MSHAPE,0,2D  
MSHKEY,1
AMESH,1  
FINISH   
  
/SOL                             
ANTYPE,4
TRNOPT,FULL                     !完全法瞬態分析
KSEL,S,KP,,1,3
DK,ALL, , , ,0,ALL, , , , , ,   
OUTRES,ALL,1
ALPHAD,5,                       !α阻尼
  
TIME,2                          !定義載荷曲線
AUTOTS,1
NSUBST,50, , ,1      
KBC,0   
SFA,ALL,1,PRES,500  
LSWRITE,1,                       
   
TIME,3   
LSWRITE,2,   
  
TIME,4
SFA,ALL,1,PRES,150  
KBC,1   
LSWRITE,3,   
  
TIME,5
SFA,ALL,1,PRES,
LSWRITE,4,   
  
LSSOLVE,1,4,1,                  !求解
FINISH   
   
/POST26                         !觀察變形隨時間的變化
NSOL,2,177,U,Y,uyy   
PLVAR,2
FINISH #p#分頁標題#e#