在CAD中獲取當(dāng)前顯示范圍的左下角和右上角坐標(biāo)

背景：我想在CAD中插入ArcServer發(fā)布的服務(wù)，那么首先要在CAD下獲取一個(gè)范圍，以當(dāng)前顯示范圍為例，代碼如下：

'————————————————————————————————
'名稱：GetActiveRange
'作者：羅簡(jiǎn)單
'日期：2010-8-3
'功能：獲取當(dāng)前顯示范圍
'————————————————————————————————
Public Sub GetActiveRange(varWS As Variant, varEN As Variant)
  '思路：1、先獲取當(dāng)前顯示范圍的中心點(diǎn)、高度、和當(dāng)前范圍像素X、Y；
  '      2、根據(jù)高度、像素X、Y求出寬度
  '      3、根據(jù)中心點(diǎn)、高度、寬度求出范圍
  '系統(tǒng)變量的意義：
  'VIEWCTR：獲取當(dāng)前顯示范圍中心點(diǎn)坐標(biāo)
  'VIEWSIZE：獲取當(dāng)前顯示范圍高度
  'SCREENSIZE：獲取當(dāng)前顯示范圍的大小（X和Y，以像素為單位存儲(chǔ)）
 
  Dim varCenter As Variant  '中心點(diǎn)
  Dim dblHeight As Double  '高度
  Dim dblWidth As Double  '寬度
  Dim varRange As Variant  '像素范圍
  varCenter = ThisDrawing.GetVariable("VIEWCTR")  '獲取中心點(diǎn)坐標(biāo)
  dblHeight = ThisDrawing.GetVariable("VIEWSIZE")  '獲取高度
  varRange = ThisDrawing.GetVariable("SCREENSIZE") '獲取像素單位X和Y
  dblWidth = dblHeight * varRange(0) / varRange(1) '計(jì)算出寬度
 
  Dim dblWS(2) As Double  '西南角坐標(biāo)
  Dim dblEN(2) As Double  '東北角坐標(biāo)
  dblWS(0) = varCenter(0) - dblWidth / 2
  dblWS(1) = varCenter(1) - dblHeight / 2
  dblEN(0) = varCenter(0) + dblWidth / 2
  dblEN(1) = varCenter(1) + dblHeight / 2
  varWS = dblWS
  varEN = dblEN
End Sub