這兩天很忙，源于自己對論文中可能出現的問題估計不足，不過話說回來，很多問題著實也是在實踐過程中才發現其中奧秘。不過這段時間效率低下是一定的了，想必和網上多了有很大關系。看來是我真正下決心息網的時候到了，成功的前提是有選擇性地放棄，看來這句話是對我說的。而且，看著即將完成的一篇論文，怎么看怎么像是我寫博客的風格，囧。博客對生活影響真大啊！
好了，言歸正傳，剛才在仿真論壇發現了一篇好貼《高效耦合小程序》，si13儼然是個天才，程序寫得太牛了，我讀了三遍才理解其中奧秘，不禁嘖嘖稱奇。對其作品更是五體投地，相當佩服。首先來圍觀下面si13編寫的APDL代碼：
說明：其中加粗的部分需要根據不同的分析自行修改。
!**************************************
allsel                                         !最好保留這句命令
!*******將從屬節點編號依次存入數組****************
cmsel,s,slavenode
*get,count1_node,node,0,count
*del,slave_node
*dim,slave_node,array,count1_node
*get,slave_node(1),node,0,num,min
*do,i,2,count1_node
  slave_node(i)=ndnext(slave_node(i-1))
*enddo
!*******將主節點編號依次存入數組****************
allsel
cmsel,s,masternode
*get,count2_node,node,0,count
*del,master_node
*dim,master_node,array,count2_node
*get,master_node(1),node,0,num,min
*do,i,2,count2_node
  master_node(i)=ndnext(master_node(i-1))
*enddo
!********將與從屬節點耦合的節點數組初始化****************
*del,cp_node
*dim,cp_node,array,count1_node
*do,i,1,count1_node
    cp_node(i)=0
*enddo
!*********開始選擇程序****************
allsel
cmsel,s,masternode
*do,i,1,count1_node     
    kk=1  
    k=1 
  
     *dowhile,kk   
      k=nnear(slave_node(i))
    nsel,s,cp,,all
    kk=nsel(k)+0.001  
    allsel
       cmsel,s,masternode
        nsel,u,node,,k
        cm,masternode,node      
        *enddo  
          
    cp_node(i)=k  
     
*enddo
!*******選擇完畢****************
!*******開始耦合****************
allsel,all
/prep7
*do,i,1,count1_node
    cp,next,UX,slave_node(i),cp_node(i)
    cp,next,UY,slave_node(i),cp_node(i)
    cp,next,UZ,slave_node(i),cp_node(i)
*enddo
!*******耦合完畢****************
過去常見的耦合命令，主要分三步(以鋼筋與混凝土耦合為例)：
選擇鋼筋線上的節點；
通過新定義的數組，對這些節點進行排序；
用一個循環，是這些鋼筋上的節點與其周圍最近的節點進行耦合。
最常見的耦合命令流如下(這是我兩年前做另一個課題的時候用的)：
cmsel,s,ouhe
*get,max1,node,0,count  !取得節點數目
*dim,steel,,max1 !定義“節點數”長度的數組
*get,nod1,node,0,num,min !最小節點編號定義給nod1
steel(1)=nod1 !數組第一個位置是最小節點的編號
*do,i,2,max1 !對數組進行排序
steel(i)=ndnext(steel(i-1))
*enddo
allsel
nsel,all !選擇全部節點
jj=1
*do,i,1,max1 !對數組中的節點，一一與周圍和它最近的節點進行耦合
cp,jj,ux,steel(i),nnear(steel(i))
cp,jj+1,uy,steel(i),nnear(steel(i))
cp,jj+2,uz,steel(i),nnear(steel(i))
jj=jj+3
*enddo
這樣做其實是很大弊端的，還是拿鋼筋混凝土舉例：用上面的代碼，容易使得鋼筋上的節點與鋼筋上另外的節點、或者與混凝土中兩個節點進行耦合——也就是說，會出現一對多的情況，而這在耦合中是不允許的。
在我兩年前的那次分析，做的是一個組合結構，不是鋼筋混凝土，而且我在網格劃分的時候，特別注意了讓參與耦合的兩對節點舉例比其他節點更接近。這樣就使得用上面的命令實現完美一對一耦合。但在網格不好控制的時候，麻煩可就大了。
所以后來見過一種改進的方法，將混凝土中的節點也進行排號，然后進行與鋼筋節點進行耦合。這樣成功地避免了自己耦合自己的情況，但已經耦合過的節點二次被耦合，則依然容易出現。
si13的這套命令流，應該是把所有問題都解決了，perfect! 下面對他的程序詳細地研究研究，學習一下他的編程思想，所以有必要把他的程序再寫一遍~
為了便于理解，下面仍以鋼筋與混凝土耦合為例，不再區分主節點與附節點。
allsel          !全部選擇
!將鋼筋中節點存入數組
cmsel,s,slavenode !選擇鋼筋節點
*get,count1_node,node,0,count !得到鋼筋節點的總數
*del,slave_node !清空數組變量，相當于slave_node=
*dim,slave_node,array,count1_node !定義用來“盛裝”鋼筋節點的數組
*get,slave_node(1),node,0,num,min !開始對鋼筋節點進行排序，并存入數組
*do,i,2,count1_node
  slave_node(i)=ndnext(slave_node(i-1))
*enddo
!**下面是將混凝土中節點存入數組，方法同上，于是就不解釋了
allsel
cmsel,s,masternode
*get,count2_node,node,0,count
*del,master_node
*dim,master_node,array,count2_node
*get,master_node(1),node,0,num,min
*do,i,2,count2_node
  master_node(i)=ndnext(master_node(i-1))
*enddo
!*新定義一個數組，專門用來存放混凝土中參與耦合的節點編號
*del,cp_node
*dim,cp_node,array,count1_node
*do,i,1,count1_node
    cp_node(i)=0
*enddo
!*最精妙的核心代碼來啦
allsel
cmsel,s,masternode   !選擇混凝土中的節點
!外層循環是為了給cp_node數組賦值，所以數組中元素個數為鋼筋節點數
*do,i,1,count1_node     
    kk=1  
    k=1  
!內層循環是為了判斷鋼筋最近的節點是否已經參與過耦合
     *dowhile,kk    !循環條件，若kk>0則循環繼續，若kk<=0則循環終止
      k=nnear(slave_node(i))  !將距鋼筋中第i個節點最近的節點編號賦給k
    nsel,s,cp,,all  !選擇所有已經耦合的節點，這種用法我是第一次看到
    kk=nsel(k)+0.001    !若上面的節點k不曾參與過耦合，則nsel命令不能將其選中，此處nsel(k)=-1，kk=-0.999<0，此部分循環終止；若上面的節點k已經參與過耦合，則nsel命令可以將其選中，此處nsel(k)=1，kk=1.001>0，循環繼續，查找其他與第i個鋼筋節點最近的混凝土節點的情況。
    allsel
       cmsel,s,masternode  !選擇混凝土節點
        nsel,u,node,,k    !排除出剛才確定的準備參加耦合的混凝土節點
        cm,masternode,node        !重新定義混凝土節點選擇集，這是為了下次選擇節點的時候，不將已經判讀過的節點放在考慮之列
        *enddo  
          
    cp_node(i)=k    !將經過判斷的k點編號賦予給混凝土參與耦合數組
     
*enddo
!開始耦合，耦合對象為鋼筋中全部節點，以及混凝土中一部分專門用來耦合的節點，二者一一對應，而且還位置確定。
allsel,all
/prep7
*do,i,1,count1_node
    cp,next,UX,slave_node(i),cp_node(i)
    cp,next,UY,slave_node(i),cp_node(i)
    cp,next,UZ,slave_node(i),cp_node(i)
*enddo
完畢，這個程序越看越喜歡~留在這里，當個記錄，用的時候過來拿，哈哈。